components_photos_PhotoDetails.bs

import "pkg:/source/roku_modules/log/LogMixin.brs"
import "pkg:/source/translationKeys.bs"
import "pkg:/source/utils/config.bs"
import "pkg:/source/utils/misc.bs"
import "pkg:/source/utils/translate.bs"

sub init()
  m.log = new log.Logger("PhotoDetails")
  m.top.isOptionsAvailable = true
  m.top.isOverhangVisible = false
  m.slideshowTimer = m.top.findNode("slideshowTimer")
  m.slideshowTimer.observeField("fire", "nextSlide")
  m.status = m.top.findNode("status")
  m.textBackground = m.top.findNode("background")
  m.statusTimer = m.top.findNode("statusTimer")
  m.statusTimer.observeField("fire", "statusUpdate")
  userSettings = m.global.user.settings
  m.slideshow = userSettings.photosSlideshow = true
  m.random = userSettings.photosRandom = true

  m.showStatusAnimation = m.top.findNode("showStatusAnimation")
  m.hideStatusAnimation = m.top.findNode("hideStatusAnimation")

  onItemContentChanged()
end sub

sub onItemContentChanged()
  if isValidToContinue(m.top.itemIndex)
    m.LoadLibrariesTask = createObject("roSGNode", "LoadPhotoTask")
    if isValid(m.top.itemsNode)
      ' itemsNode IS the ContentNode containing photo children
      if m.top.itemsNode.getChildCount() > 0
        m.LoadLibrariesTask.itemNodeContent = m.top.itemsNode.getChild(m.top.itemIndex)
      else if isValidAndNotEmpty(m.top.itemsNode.id)
        ' Single photo node passed directly
        m.LoadLibrariesTask.itemNodeContent = m.top.itemsNode
      end if
    else if isValid(m.top.itemsArray)
      itemContent = m.top.itemsArray[m.top.itemIndex]
      m.LoadLibrariesTask.itemArrayContent = itemContent
    else
      return
    end if

    m.LoadLibrariesTask.observeField("results", "onPhotoLoaded")
    m.LoadLibrariesTask.control = "RUN"
  end if
end sub

sub onPhotoLoaded()
  stopLoadingSpinner()
  if isValid(m.LoadLibrariesTask.results)
    photo = m.top.findNode("photo")
    photo.uri = m.LoadLibrariesTask.results

    if m.slideshow = true or m.random = true
      ' user has requested either a slideshow or random...
      m.slideshowTimer.control = "start"
    end if
  else
    'Show user error here (for example if it's not a supported image type)
    messageDialog(translate(translationKeys.ErrorImageTypeNotSupported))
  end if
end sub

sub nextSlide()
  m.slideshowTimer.control = "stop"

  if m.slideshow = true
    if isValidToContinue(m.top.itemIndex + 1)
      m.top.itemIndex++
      m.slideshowTimer.control = "start"
    end if
  else if m.random = true
    index = invalid

    if isValid(m.top.itemsNode)
      ' itemsNode IS the ContentNode containing photo children
      if m.top.itemsNode.getChildCount() > 0
        index = rnd(m.top.itemsNode.getChildCount() - 1)
      else
        ' we're dealing with a single photo
        return
      end if
    else if isValid(m.top.itemsArray)
      if m.top.itemsArray.count() > 0
        index = rnd(m.top.itemsArray.count() - 1)
      end if
    end if

    if isValid(index) and isValidToContinue(index)
      m.top.itemIndex = index
      m.slideshowTimer.control = "start"
    end if
  end if
end sub

sub statusUpdate()
  m.statusTimer.control = "stop"
  m.hideStatusAnimation.control = "start"
end sub

' JRScreen hook.
' Used to ensure tasks are stopped
sub onScreenHidden()
  m.slideshowTimer.control = "stop"
  m.statusTimer.control = "stop"
end sub

' isSlideshow component field has changed
sub onIsSlideshowChanged()
  m.slideshow = m.top.isSlideshow
end sub

' isRandom component field has changed
sub onIsRandomChanged()
  m.random = m.top.isRandom
end sub

function onKeyEvent(key as string, press as boolean) as boolean
  if not press then return false

  if key = "right"
    if isValidToContinue(m.top.itemIndex + 1)
      m.slideshowTimer.control = "stop"
      m.top.itemIndex++
    end if
    return true
  end if

  if key = "left"
    if isValidToContinue(m.top.itemIndex - 1)
      m.slideshowTimer.control = "stop"
      m.top.itemIndex--
    end if
    return true
  end if

  if key = "play"
    if m.slideshowTimer.control = "start"
      ' stop the slideshow if the user hits "pause"
      m.slideshowTimer.control = "stop"
      m.status.text = translate(translationKeys.LabelSlideshowPaused)
      if m.textBackground.opacity = 0
        m.showStatusAnimation.control = "start"
      end if
      m.statusTimer.control = "start"
    else
      ' start the slideshow if the user hits "play"
      m.status.text = translate(translationKeys.LabelSlideshowResumed)
      if m.textBackground.opacity = 0
        m.showStatusAnimation.control = "start"
      end if
      m.slideshow = true
      m.statusTimer.control = "start"
      m.slideshowTimer.control = "start"
    end if
    return true
  end if

  if key = "options"
    ' Options (random etc) is done on itemGrid
    return true
  end if

  return false
end function

' onDestroy: Full teardown releasing all resources before component removal
' Called automatically by SceneManager.popScene() / clearScenes()
sub onDestroy()
  m.log.verbose("onDestroy")

  ' Unobserve timer observers
  m.slideshowTimer.unobserveField("fire")
  m.statusTimer.unobserveField("fire")

  ' Stop timers (may already be stopped by onScreenHidden or user interaction)
  m.slideshowTimer.control = "stop"
  m.statusTimer.control = "stop"

  ' Stop and release task node (may be invalid if photo loading hadn't started)
  if isValid(m.LoadLibrariesTask)
    m.LoadLibrariesTask.unobserveField("results")
    m.LoadLibrariesTask.control = "STOP"
    m.LoadLibrariesTask = invalid
  end if

  ' Clear node references
  m.slideshowTimer = invalid
  m.status = invalid
  m.textBackground = invalid
  m.statusTimer = invalid
  m.showStatusAnimation = invalid
  m.hideStatusAnimation = invalid
end sub

function isValidToContinue(index as integer)
  if isValid(m.top.itemsNode)
    ' itemsNode IS the ContentNode containing photo children
    childCount = m.top.itemsNode.getChildCount()
    if childCount > 0
      if index >= 0 and index < childCount
        return true
      end if
    else if isValidAndNotEmpty(m.top.itemsNode.id) and index = 0
      ' Single photo node passed directly
      return true
    end if
  else if isValidAndNotEmpty(m.top.itemsArray)
    if index >= 0 and index < m.top.itemsArray.count()
      return true
    end if
  end if

  return false
end function